AES128_BytesMode

Encrypts or decrypts an array of Bytes using a specified mode.

VB6/VBA

Debug.Print "Testing AES128_BytesMode ..."
Dim nRet As Long
Dim strOutput As String
Dim strInput As String
Dim sCorrect As String
Dim abKey()  As Byte
Dim abInitV() As Byte
Dim abResult() As Byte
Dim abData() As Byte
Dim nDataLen As Long

' Set up input in byte arrays
strInput = "Now is the time for all good men"
sCorrect = "C3153108A8DD340C0BCB1DFE8D25D2320EE0E66BD2BB4A313FB75C5638E9E177"
abKey = cnvBytesFromHexStr("0123456789ABCDEFF0E1D2C3B4A59687")
abInitV = cnvBytesFromHexStr("FEDCBA9876543210FEDCBA9876543210")
abData = StrConv(strInput, vbFromUnicode)
nDataLen = UBound(abData) - LBound(abData) + 1

' Pre-dimension output array
ReDim abResult(nDataLen - 1)

Debug.Print "KY=", cnvHexStrFromBytes(abKey)
Debug.Print "IV=", cnvHexStrFromBytes(abInitV)
Debug.Print "PT=", cnvHexStrFromBytes(abData)
' Encrypt in one-off process
nRet = AES128_BytesMode(abResult(0), abData(0), nDataLen, abKey(0), _
    ENCRYPT, "CBC", abInitV(0))
Debug.Print "CT=", cnvHexStrFromBytes(abResult)
Debug.Print "OK=", sCorrect

' Now decrypt back
nRet = AES128_BytesMode(abData(0), abResult(0), nDataLen, abKey(0), _
    DECRYPT, "CBC", abInitV(0))
strOutput = StrConv(abData(), vbUnicode)
Debug.Print "P'=", strOutput

' Check
Debug.Assert (strOutput = strInput)

Output

Testing AES128_BytesMode ...
KY=   0123456789ABCDEFF0E1D2C3B4A59687
IV=   FEDCBA9876543210FEDCBA9876543210
PT=   4E6F77206973207468652074696D6520666F7220616C6C20676F6F64206D656E
CT=   C3153108A8DD340C0BCB1DFE8D25D2320EE0E66BD2BB4A313FB75C5638E9E177
OK=   C3153108A8DD340C0BCB1DFE8D25D2320EE0E66BD2BB4A313FB75C5638E9E177
P'=   Now is the time for all good men

VB.NET

Console.WriteLine("Testing AES128_BytesMode ...")
''Dim nRet As Integer
Dim strOutput As String
Dim strInput As String
Dim sCorrect As String
Dim abKey() As Byte
Dim abInitV() As Byte
Dim abResult() As Byte
Dim abData() As Byte
''Dim nDataLen As Integer

' Set up input in byte arrays
strInput = "Now is the time for all good men"
sCorrect = "C3153108A8DD340C0BCB1DFE8D25D2320EE0E66BD2BB4A313FB75C5638E9E177"
abKey = Cnv.FromHex("0123456789ABCDEFF0E1D2C3B4A59687")
abInitV = Cnv.FromHex("FEDCBA9876543210FEDCBA9876543210")
abData = System.Text.Encoding.Default.GetBytes(strInput)
''nDataLen = UBound(abData) - LBound(abData) + 1

' Pre-dimension output array
''ReDim abResult(nDataLen - 1)

Console.WriteLine("KY=" & Cnv.ToHex(abKey))
Console.WriteLine("IV=" & Cnv.ToHex(abInitV))
Console.WriteLine("PT=" & Cnv.ToHex(abData))
' Encrypt in one-off process
abResult = Aes128.Encrypt(abData, abKey, Mode.CBC, abInitV)
Console.WriteLine("CT=" & Cnv.ToHex(abResult))
Console.WriteLine("OK=" & sCorrect)

' Now decrypt back
abData = Aes128.Decrypt(abResult, abKey, Mode.CBC, abInitV)
strOutput = System.Text.Encoding.Default.GetString(abData)
Console.WriteLine("P'=" & strOutput)

' Check
Debug.Assert(strOutput = strInput)

[Contents]